# Last edited : 21/10/96 (MM - new UQ modem bank numbers)
#
# set up some strings for dialling up
#
if ![load $modeminit]
$modeminit="&f\n5%c1"
save $modeminit
end
$prompt = "nnex:"
$userprompt = "sername:"
$passprompt = "assword:"
$slipcmd = "slip"
$addrtarg = "ur address is"
$pppcmd = "ppp"
%attempts = 10
#
#
#----------------------------------------------------------
#
# initialize modem
#
output "atz" \13
if ! [input 10 OK\n]
display "Modem is not responding"\n
abort
end
#
# setup our modem commands
#
output "at"$modeminit \13
input 10 OK\n
#
# send phone number
#
%pn = 0
%n = 0
repeat
if %n = %attempts
display "Too many dial attempts"\n
abort
end
sleep 2
#
# Select a telephone number
display "PAYING CLIENTS ONLY banks ."\n
display "A. 3291 2577 : 300 - 28.8k(V.34 and V.fast)"\n
display "B. 3870 7257 : 300 - 28.8k(V.34)"\n
display \n
display "STUDENTS and STAFF ONLY banks."\n
display "C. 33354099 : 300 - 28.8k(V.34 and V.fast)"\n
display "D. 38703227 : 300 - 28.8k(V.34) General use."\n
display \n
display "STAFF ONLY bank ."\n
display "E. 33354079 : 300 - 28.8k(V.34 and V.Fast)"\n
display \n
display "FAST TURN AROUND bank. (general access)"\n
display "F. 33354089 : 300 - 28.8k(V.34 and V.fast)"\n
display \n
display "G. User specified"\n
query $pn "Select A, B, C, D, E, F or G."
if ($pn="A") | ($pn="a")
output atdt32912577\13
%pn = 1
end
if ($pn="B") | ($pn="b")
output atdt38707257\13
%pn = 1
end
if ($pn="C") | ($pn="c")
output atdt33354099\13
%pn = 1
end
if ($pn="D") | ($pn="d")
output atdt38703227\13
%pn = 1
end
if ($pn="E") | ($pn="e")
output atdt33354079\13
%pn = 1
end
if ($pn="F") | ($pn="f")
output atdt33354089\13
%pn = 1
end
if ($pn="G") | ($pn="g")
query $number "Enter phone number"
output atdt$number\13
%pn = 1
end
if !%pn
abort
end
#
# now we should be connected.
#
%ok = [input 60 CONNECT]
%n = %n + 1
until %ok
#
# wait till it's safe to send because some modem's hang up
# if you transmit during the connection phase
#
wait 30 dcd
#
# now prod the terminal server
#
output \13
#
# wait for the username prompt
#
input 30 $userprompt
username "Enter your username"
output \u\13
#
# and the password
#
input 30 $passprompt
password "Enter your password"
output \p\13
#
# we are now logged in
#
input 30 $prompt
#
if %ppp
#
# jump into ppp mode
#
output $pppcmd\13
#
input 30\n
#
display "PPP mode selected. Will try to negotiate IP address."\n
#
else
#
# jump into slip mode
#
output $slipcmd\13
#
# wait for the address string
#
input 30 $addrtarg
#
# parse address
#
address 30
input 30\n
#
# we are now connected, logged in and in slip mode.
#
display \n
display "Connected - your address is "\i\n
end
#
# now we are finished.
#
;
; This is a script file that demonstrates how
; to establish a ppp connection with a host.
;
; A script file must have a 'main' procedure.
; All script execution starts with this 'main'
; procedure.
;
; Main entry point to script
;
proc main
; Change these variables to customize for your
; specific Internet service provider.
integer nTries = 3
; This is the login prompt and timeout values
string szLogin = "username:"
integer nLoginTimeout = 3
; This is the password prompt and timeout values
string szPW = "password:"
integer nPWTimeout = 3
; This is the prompt once your password is verified
string szPrompt = "annex:"
; This is the command to send to establish the
; connection. This script assumes you only need
; to issue one command to continue. Feel free
; to add more commands if your provider requires
; it.
string szConnect = "ppp^M"
; Set this to FALSE if you don't want to get an IP
; address
boolean bUseSlip = FALSE
; Delay for 2 seconds first to make sure the
; host doesn't get confused when we send the
; two carriage-returns.
delay 2
transmit "^M^M"
; Attempt to login at most 'nTries' times
while 0 < nTries do
; Wait for the login prompt before entering
; the user ID, timeout after x seconds
waitfor szLogin then DoLogin
until nLoginTimeout
TryAgain:
transmit "^M" ; ping
nTries = nTries - 1
endwhile
goto BailOut
DoLogin:
; Enter user ID
transmit $USERID, raw
transmit "^M"
; Wait for the password prompt
waitfor szPW until nPWTimeout
if FALSE == $SUCCESS then
goto TryAgain
endif
; Send the password
transmit $PASSWORD, raw
transmit "^M"
; Wait for the prompt
waitfor szPrompt
transmit szConnect
if bUseSlip then
; An alternative to the following line is
;
; waitfor "Your address is "
; set ipaddr getip
;
; if we don't know the order of the IP addresses.
set ipaddr getip 2
endif
goto Done
BailOut:
; Something isn't responding. Halt the script
; and let the user handle it manually.
set screen keyboard on
halt
Done:
endproc
# RoboDun PPP login script for Window 95
# Send CR/LF to get the ball rolling
Send ""
# Wait 10 seconds for "username" prompt
WaitFor "sername:", 10
# Send user name in response to "NetLogin:"
Send "username<cr>"
# Wait 10 second for "Password:" prompt
WaitFor "assword:", 10
# Send password in response to prompt
Send "password<cr>"
# Wait for "Annex:" prompt
WaitFor "nnex:", 10
# Specify service...PPP in this case
Send "ppp<cr>"
Done
! Basic Annex Gateway Script version 1.0a
! Rick Ernst
!
! InterSLIP gateway script for Annex terminal server which has
! been configured to give users a command line interface to the
! terminal server.
!
!
settries 0
note "Giving the annex a second.."
pause 30
!
! Most Annex terminal servers give a "Annex username:" prompt.
! Some do a "MachineName username:" so we look for "username".
!
@login
note "Sending carriage returns waiting to be prompted for username..."
write "\13\13\13"
matchstr 1 username "username:"
matchread 60
note "Trying again ..."
inctries
iftries 5 unsuccessful
jump login
!
@username
note "Sending username ... ^5"
write "^5\13"
matchclr
matchstr 1 password "password:"
matchread 120
note "Gateway not responding!"
jump unsuccessful
!
@password
note "Sending password"
write "^6\13"
matchclr
matchstr 1 denied "Username/Password Incorrect"
matchstr 2 successful "Permission granted"
matchread 240
jump unsuccessful
!
@denied
note "Access Denied, Bad password?"
jump unsuccessful
!
@successful
note "Waiting for annex prompt..."
matchclr
matchstr 1 slip "annex"
matchread 240
jump unsuccessful
!
@slip
note "Sending slip command"
write "slip\13"
matchclr
matchstr 1 address "Your address"
matchread 240
jump unsuccessful
!
@address
note "Waiting for your address..."
matchclr
matchexp 1 connected "[0-9]*\\.[0-9]*\\.[0-9]*\\.[0-9]*"
matchread 60
jump unsuccessful
!
@connected
note "Your address is: ^0"
setip "^0"
setmtu "^9"
pause 60
exit 0
!
! currently unused:
!
@answer
@hangup
exit 0
!
!
@unsuccessful
note "SLIP Connection was unsuccessful"
sound Indigo
pause 60
exit -1
Below is a shar file which will install the file ppp.nopasswd. Mv this to ppp, then follow the installation instructions inside the file. If you have any problems with this, feel free to email me at robert@zen.humbug.org.au.